Gecko [ goons4good.org ]

Name	Size	Permission	Date
internal	[ DIR ]	drwxr-xr-x	2021-09-16 10:43
amversion.m4	1.58 KB	-rw-r--r--	2014-06-10 04:03
ar-lib.m4	1.98 KB	-rw-r--r--	2014-06-10 04:03
as.m4	767 B	-rw-r--r--	2014-06-10 04:03
auxdir.m4	2.37 KB	-rw-r--r--	2014-06-10 04:03
cond-if.m4	1.01 KB	-rw-r--r--	2014-06-10 04:03
cond.m4	1.01 KB	-rw-r--r--	2014-06-10 04:03
depend.m4	7.11 KB	-rw-r--r--	2014-06-10 04:03
depout.m4	2.93 KB	-rw-r--r--	2014-06-10 04:03
dmalloc.m4	906 B	-rw-r--r--	2014-06-10 04:03
extra-recurs.m4	738 B	-rw-r--r--	2014-06-10 04:03
gcj.m4	649 B	-rw-r--r--	2014-06-10 04:03
init.m4	5.78 KB	-rw-r--r--	2014-06-10 04:03
install-sh.m4	677 B	-rw-r--r--	2014-06-10 04:03
lead-dot.m4	641 B	-rw-r--r--	2014-06-10 04:03
lex.m4	689 B	-rw-r--r--	2014-06-10 04:03
lispdir.m4	2.1 KB	-rw-r--r--	2014-06-10 04:03
maintainer.m4	1.62 KB	-rw-r--r--	2014-06-10 04:03
make.m4	1.3 KB	-rw-r--r--	2014-06-10 04:03
minuso.m4	1.25 KB	-rw-r--r--	2014-06-10 04:03
missing.m4	1.13 KB	-rw-r--r--	2014-06-10 04:03
mkdirp.m4	1.32 KB	-rw-r--r--	2014-06-10 04:03
obsolete.m4	1008 B	-rw-r--r--	2014-06-10 04:03
options.m4	1.06 KB	-rw-r--r--	2014-06-10 04:03
python.m4	8.87 KB	-rw-r--r--	2014-06-10 04:03
runlog.m4	718 B	-rw-r--r--	2014-06-10 04:03
sanity.m4	2.58 KB	-rw-r--r--	2014-06-10 04:03
silent.m4	1.87 KB	-rw-r--r--	2014-06-10 04:03
strip.m4	1.36 KB	-rw-r--r--	2014-06-10 04:03
substnot.m4	675 B	-rw-r--r--	2014-06-10 04:03
tar.m4	4.37 KB	-rw-r--r--	2014-06-10 04:03
upc.m4	836 B	-rw-r--r--	2014-06-10 04:03
vala.m4	1.62 KB	-rw-r--r--	2014-06-10 04:03

Rename

##                                                          -*- Autoconf -*-
# Copyright (C) 2011-2013 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_PROG_AR([ACT-IF-FAIL])
# -------------------------
# Try to determine the archiver interface, and trigger the ar-lib wrapper
# if it is needed.  If the detection of archiver interface fails, run
# ACT-IF-FAIL (default is to abort configure with a proper error message).
AC_DEFUN([AM_PROG_AR],
[AC_BEFORE([$0], [LT_INIT])dnl
AC_BEFORE([$0], [AC_PROG_LIBTOOL])dnl
AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
AC_REQUIRE_AUX_FILE([ar-lib])dnl
AC_CHECK_TOOLS([AR], [ar lib "link -lib"], [false])
: ${AR=ar}

AC_CACHE_CHECK([the archiver ($AR) interface], [am_cv_ar_interface],
  [am_cv_ar_interface=ar
   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int some_variable = 0;]])],
     [am_ar_try='$AR cru libconftest.a conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
      AC_TRY_EVAL([am_ar_try])
      if test "$ac_status" -eq 0; then
        am_cv_ar_interface=ar
      else
        am_ar_try='$AR -NOLOGO -OUT:conftest.lib conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
        AC_TRY_EVAL([am_ar_try])
        if test "$ac_status" -eq 0; then
          am_cv_ar_interface=lib
        else
          am_cv_ar_interface=unknown
        fi
      fi
      rm -f conftest.lib libconftest.a
     ])
   ])

case $am_cv_ar_interface in
ar)
  ;;
lib)
  # Microsoft lib, so override with the ar-lib wrapper script.
  # FIXME: It is wrong to rewrite AR.
  # But if we don't then we get into trouble of one sort or another.
  # A longer-term fix would be to have automake use am__AR in this case,
  # and then we could set am__AR="$am_aux_dir/ar-lib \$(AR)" or something
  # similar.
  AR="$am_aux_dir/ar-lib $AR"
  ;;
unknown)
  m4_default([$1],
             [AC_MSG_ERROR([could not determine $AR interface])])
  ;;
esac
AC_SUBST([AR])dnl
])